From news-rocq.inria.fr!univ-lyon1.fr!swidir.switch.ch!scsing.switch.ch!news.dfn.de!zeus.rbi.informatik.uni-frankfurt.de!terra.wiwi.uni-frankfurt.de!news.th-darmstadt.de!zib-berlin.de!netmbx.de!Germany.EU.net!EU.net!howland.reston.ans.net!gatech!newsxfe Wed Apr  6 15:59:54 1994
Article: 585 of rec.games.corewar
Newsgroups: rec.games.corewar
Path: news-rocq.inria.fr!univ-lyon1.fr!swidir.switch.ch!scsing.switch.ch!news.dfn.de!zeus.rbi.informatik.uni-frankfurt.de!terra.wiwi.uni-frankfurt.de!news.th-darmstadt.de!zib-berlin.de!netmbx.de!Germany.EU.net!EU.net!howland.reston.ans.net!gatech!newsxfer.itd.umich.edu!zip.eecs.umich.edu!yeshua.marcam.com!news.kei.com!news.byu.edu!cwis.isu.edu!u.cc.utah.edu!math.utah.edu!news.math.utah.edu!morrell
From: morrell@math.utah.edu (Steven C. Morrell)
Subject: Montage
Sender: news@math.utah.edu
Date: Mon, 4 Apr 1994 22:22:43 GMT
Organization: Department of Mathematics, University of Utah
Message-ID: <MORRELL.94Apr4162244@uglab6.math.utah.edu>
Lines: 118

Here is the code for Montage, my first real attempt at an imp-stone combo.
The most important contribution this program makes is that it has a new
stone in it.  I had a tough time deciding whether I wanted gate-breaking
imps or 7-pt imps, so I just put both of them in.  The gate-breaking imps
are closer together than in Cannonade, making them less vulnerable to SPL
bombs but more vulnerable to imp-traps.  (Imp traps?  I forgot to mention
them in chapter 1.  OH NO!!!)  The stone is a mega-self-splitting stone
that's a bit bigger than Extra-Extra, but maybe a little more durable
because it has 2 SPL 0's.  It bombs core with a mod-1 pattern until it
hits itself, at which time it runs a subtraction core-clear.  After that,
mostly for cosmetic purposes, it jumps to an imp-gate.  Of course, by that
time, any free imps should have overrun everything, so I'm not sure it's
worth the extra cycle to plant the imp-gate.

;redcode verbose
;name Montage
;kill Montage
;author Steven Morrell
;strategy  Stone and a bunch of imps and an imp gate.

p1 equ boot+300
p2 equ boot+302+2667
p3 equ boot+303
p4 equ boot+400

stone   spl 0,<-50
        spl 0,<-51
        mov <3359,-3359
        add 2,-1
        djn -2,<-54
        dat <3359,<-3359

imp1    mov 0,2667
imp2    mov 0,2668
imp4    mov 0,1143
gate    jmp -3359,<3359-10

boot    mov stone+5,-200+5
        mov stone+4,<boot
        mov stone+3,<boot
        mov stone+2,<boot
        mov stone+1,<boot
        mov stone,<boot
        spl boot-200,<100
        mov gate,boot-200+6720
        mov imp1,p1
        mov imp2,p2
        mov imp2,p2+1
        mov imp2,p3
        mov imp2,p3+1
        mov imp4,p4
        spl b,<200
        spl ab,<300
        spl aab,<400
        spl aaab,<500
        spl aaaab,<600
        jmp p1,<700
aaaab   jmp p1+2667,<800
aaab    spl aaabb,<900
        jmp p1+5334,<1000
aaabb   jmp p1+1,<1100
aab     spl aabb,<1200
        spl aabab,<1300
        jmp p1+2668,<1400
aabab   jmp p1+5335,<1500
aabb    spl aabbb,<1600
        jmp p2,<1700
aabbb   jmp p2+2668,<1800
ab      spl abb,<1900
        spl abab,<2000
        spl abaab,<2100
        jmp p2+5336,<2200
abaab   jmp p2+4,<2300
abab    spl ababb,<2400
        jmp p2+2672,<2500
ababb   jmp p2+5340,<2600
abb     spl abbb,<2700
        spl abbab,<2800
        jmp p3,<2900
abbab   jmp p3+2668,<3000
abbb    spl abbbb,<3100
        jmp p3+5336,<3200
abbbb   jmp p3+4,<3300
b       spl bb,<3400
        spl bab,<3500
        spl baab,<3600
        spl baaab,<3700
        jmp p3+2672,<3800
baaab   jmp p3+5340,<3900
baab    spl baabb,<4000
        jmp p4,<4100
baabb   jmp p4+1143,<4200
bab     spl babb,<4300
        spl babab,<4400
        jmp p4+2286,<4500
babab   jmp p4+3429,<4600
babb    spl babbb,<4700
        jmp p4+4572,<4800
babbb   jmp p4+5715,<4900
bb      spl bbb,<5000
        spl bbab,<5100
        spl bbaab,<5200
        jmp p4+6858,<5300
bbaab   jmp p4+1,<5400
bbab    spl bbabb,<5500
        jmp p4+1144,<5600
bbabb   jmp p4+2287,<5700
bbb     spl bbbb,<5800
        spl bbbab,<5900
        jmp p4+3430,<6000
bbbab   jmp p4+4573,<6100
bbbb    spl bbbbb,<6200
        jmp p4+5716,<6300
bbbbb   jmp p4+6859,<6400

end boot

Steven Morrell                   morrell@math.utah.edu